{
  pkgs,
  context,
  src,
  members,
  dependencies ? null,
}:
let
  buildTools = import ./build-tools.nix;
  config = pkgs.writeText "camino-react-contracts.json" (
    builtins.toJSON {
      source = import ./implementation-source.nix {
        inherit (pkgs) lib;
        inherit src;
      };
      interface = builtins.toFile "camino-interface-contract.json" (
        builtins.unsafeDiscardStringContext (
          builtins.toJSON (
            let
              resource = builtins.fromJSON (builtins.readFile context.interface);
            in
            {
              kind = resource.kind;
              revision = builtins.removeAttrs resource.revision [ "source" ];
            }
          )
        )
      );
      inherit members dependencies;
      reactSdk = context.reactSdk or null;
      node = "${pkgs.nodejs_24}/bin/node";
      tsc = "${context.typescript}/node_modules/typescript/bin/tsc";
    }
  );
in
pkgs.runCommand "camino-react-contracts" { } ''
  ${pkgs.nodejs_24}/bin/node ${buildTools}/build-react-contracts.mjs ${config}
''